import Quickshell
import Quickshell.Wayland
import Quickshell.Widgets
import Quickshell.Io
import QtQuick
import QtQuick.Effects

Variants {
    model: Quickshell.screens
    PanelWindow {
        id: bg
        anchors {
            top: true
            right: true
            bottom: true
            left: true
        }
        WlrLayershell.namespace: "monowall"
        exclusionMode: ExclusionMode.Ignore
        aboveWindows: false
        property var modelData
        screen: modelData
        color: "#111"
        ClippingRectangle {
            anchors.fill: parent
            Image {
                source: Quickshell.shellPath("wallpaper")
                anchors.fill: parent
                fillMode: Image.PreserveAspectCrop
            }
            radius: 40
            PropertyAnimation on radius {
                id: radiusAnimation
                running: false
                to: 14
                duration: 1000
            }
            transform: [
                Translate {
                    y: 160
                    PropertyAnimation on y {
                        duration: 500
                        to: 0
                        easing.type: Easing.OutCubic
                        onFinished: scaleAnimation.start()
                    }
                },
                Scale {
                    origin { x: width/2; y: height/2 }
                    xScale: 0.8
                    yScale: xScale
                    PropertyAnimation on xScale {
                        id: scaleAnimation
                        running: false
                        duration: 1000
                        to: 1
                        easing.type: Easing.InOutCubic
                        onStarted: radiusAnimation.start()
                    }
                }
            ]
        }
    }
}